Click above to get retro games delivered to your door ever month!

=              Equal -- binary                            (Relational)


Syntax:        <exp1> = <exp2>

Type:          All

Operands:      <exp1> and <exp2> are expressions of the same
               data type to be compared.

Description:   The = (equal) is a binary operator that compares two
               values of the same data type and returns true (.T.) if
               <expC1> is equal to <expC2> according to the following
               rules:

               Character: The comparison is based on the underlying
               ASCII code.  ASCII codes for alphabetic characters are
               ascending, i.e. the code for "A" is 65 and the code for
               "Z" is 90.

               When EXACT is OFF two character strings are compared
               according to the following rules; assume two character
               strings A and B where the expression to test is (A = B):

               . If B is null, return true (.T.).

               . If LEN(B) is greater than LEN(A), return false (.F.).

               . Compare all characters in B with A.  If all characters
                 in B equal A, return true (.T.); otherwise return false
                 (.F.).

               With EXACT ON, two strings must match exactly, except for
               trailing blanks.

               Date: Dates are compared according to the underlying
               date value.

               Logical: True (.T.) is equal true (.T.) and false
               (.F.) equal to false (.F.).

               Memo: Treated the same as character.

               Numeric: Compared based on magnitude.


----------------------------------- Examples -------------------------------

   * Character.
   SET EXACT ON
   ? "123"  = "123  "                   && Result: .T.
   ? " 123" = "123"                     && Result: .F.

   SET EXACT OFF
   ? "123"   = "12345"                  && Result: .F.
   ? "12345" = "123"                    && Result: .T.
   ? "123"   = ""                       && Result: .T.
   ? ""      = "123"                    && Result: .F.

   * Date.
   ? CTOD("12/12/88") =;
      CTOD("12/12/88")                  && Result: .T.

   * Logical.
   ? .T. = .T.                          && Result: .T.

   * Numeric.
   ? 2 = 1                              && Result: .F.
   ? 1 = 1                              && Result: .T.