Click above to get retro games delivered to your door ever month!

  DELETE TAG:

  Syntax:

  DELETE TAG <tagname1> [OF <cdxname1>] [,<tagname2> [OF <cdxname2>]]...
  DELETE TAG ALL [OF <cdxname>]

  <tagname> specifies the name of the tag to delete.

  OF <cdxname> specifies which .CDX file contains the specified tag.
  This is used to eliminate any conflicts between two .CDX's that may
  each have a tag of the same name.  If <cdxname> is not specified, then
  the open indexes are searched, starting with the structural (production)
  .CDX (if one exists).

  If the specified tag is the only tag in the .CDX file, then the .CDX
  file is deleted.

  DELETE TAG ALL deletes the current or specified .CDX file.

  Note that the DELETE TAG command works only with .CDX files.  This
  command has no effect on .IDX files.

    NOTE:  This command is NOT supported under SIXNTX.

    NOTE:  Be sure that an order is actually set when using
               DELETE TAG ALL. For instance, this will not work:

               USE test VIA "SIXNSX"       // TEST.NSX auto opens
               DELETE TAG ALL              // Nothing happens

               Instead, do this:

               USE test VIA "SIXNSX"       // TEST.NSX auto opens
               SET ORDER TO 1              // make sure an order is set
               DELETE TAG ALL              // tags are killed.

  Example:

    #include "SIXCDX.CH"
    USE TEST VIA "SIXCDX"

    INDEX ON last  TAG last         // Create LAST tag
    INDEX ON age   TAG age          // Create AGE tag
    INDEX ON state TAG state        // Create STATE tag
    ? Sx_TagCount()                 // Returns 3

    DELETE TAG age                  // Delete the AGE tag
    ? Sx_TagCount()                 // Returns 2

    DELETE TAG ALL                  // Delete ALL tags (erases TEST.CDX)
    ? Sx_TagCount()                 // Returns 0


  NOTE:  For DELETE TAG ALL to work properly a tag must be currently
         active.  In other words, you must not have ORDER set to 0.