Click above to get retro games delivered to your door ever month!

  Sx_ClearOrder():

  Syntax:   Sx_ClearOrder( <nOrder> )

            nOrder = The order of the index to close.


  Returns:  Logical value indicating success or failure of the action.

  Description:  Allows you to selectively close a single index without
                closing any other open indexes.  Any indexes in a greater
                order position will be moved up one order position.

    NOTE:  If you clear the active order, order is set to zero (0).

    NOTE:  This function is NOT supported under SIXNTX.


  Example:

    #include "SIXCDX.CH"

    LOCAL nX := 0

    USE test VIA "SIXCDX"                          // Open Database

    INDEX ON last  TO last                         // Create LAST.IDX
    INDEX ON state TO state ADDITIVE               // Create STATE.IDX
    INDEX ON age   TO age   ADDITIVE               // Create AGE.IDX
    INDEX ON zip   TO zip   ADDITIVE               // Create ZIP.IDX

    ? "Displaying indexes open in each order:"
    ? "--------------------------------------"
    FOR nX := 1 TO Sx_IndexCount()                   // Loop thru index order
      ? AllTrim( Str( nX )) + " " + Sx_IndexName(nX) //  displaying each one
    NEXT

    // 1 LAST.IDX
    // 2 STATE.IDX
    // 3 AGE.IDX
    // 4 ZIP.IDX

    ?
    ? "Now close the second index (STATE.IDX) only:"
    ? "--------------------------------------------"
    Sx_ClearOrder(2)                                 // Close just STATE.IDX

    FOR nX := 1 TO Sx_IndexCount()                   // Loop thru index order
      ? AllTrim( Str( nX )) + " " + Sx_IndexName(nX) //  displaying each one
    NEXT

    // 1 LAST.IDX
    // 2 AGE.IDX
    // 3 ZIP.IDX