Click above to get retro games delivered to your door ever month!

  OrdSetFocus():

  Syntax:   OrdSetFocus( [<nOrder> | [<cOrderName> [,<cIndexFile>]] )

       nOrder = A number representing the position in the Order List of the
                selected Order.

       cOrderName = The name of the selected Order (or Tag), a logical
                    ordering of a database.  OrdSetFocus() ignores any
                    invalid values of <cOrderName>.

       cIndexFile = The name of a index file containing one or more Orders.
                    You may specify <cIndexFile> as the filename with or
                    without the pathname or appropriate extension.  If you do
                    not include the extension as part of <cIndexFile>, the
                    default extension of the currently active RDD will be
                    assumed.

  Returns:

     The Order Name of the previous controlling Order.

  Description:

     OrdSetFocus() is an Order management function that returns the Order
     Name of the previous controlling Order and optionally sets the focus to
     an new Order.

     If you do not specify <cOrderName> or <nOrder>, the name of the
     currently controlling order is returned and the controlling order
     remains unchanged.

     All Orders in an Order List are properly updated no matter what
     <cOrderName> is the controlling Order.  After a change of controlling
     Orders, the record pointer still points to the same record.

     OrdSetFocus() supersedes IndexOrd().

  Examples:

     // With three seperate .NSX index files
     USE test VIA "SIXNSX"
     SET INDEX TO last, state, age
     ? OrdSetFocus( "state" )    // Displays: "LAST"
     ? OrdSetFocus()             // Displays: "STATE"

     // With a single compound .NSX index file, containing three tags
     USE test VIA "SIXNSX"           // Also opens TEST.NSX automatically
     OrdSetFocus( "last", "test" )   // Selects LAST name tag
     ? OrdSetFocus()             // Displays: "LAST"

     // With two compound .NSX index files, TEST.NSX and TEST2.NSX
     USE test VIA "SIXNSX"           // Also opens TEST.NSX automatically
     SET INDEX TO test, test2        // Adds TEST2.NSX to Order list
     ? OrdSetFocus()                 // First tag in LAST.NSX is now active
     OrdSetFocus( "zip", "test2" )   // Select ZIP tag in TEST2.NSX
     ? OrdSetFocus()                 // Displays: "ZIP"

     // With two compound .NSX index files, TEST.NSX and TEST2.NSX
     USE test VIA "SIXNSX"           // Also opens TEST.NSX automatically
     SET INDEX TO test, test2        // Adds TEST2.NSX to Order list
     ? OrdSetFocus()                 // First tag in LAST.NSX is now active
     OrdSetFocus( 4 )                // Select ZIP tag in TEST2.NSX
     ? OrdSetFocus()                 // Displays: "ZIP"