Click above to get retro games delivered to your door ever month!

#ifndef _FOLDER_CH
#define _FOLDER_CH

//----------------------------------------------------------------------------//

#xcommand @ <nRow>, <nCol> FOLDER [<oFolder>] ;
             [ <of: OF, WINDOW, DIALOG> <oWnd> ] ;
             [ <prm: PROMPT, PROMPTS, ITEMS> <cPrompt,...> ] ;
             [ <dlg: DIALOG, DIALOGS, PAGE, PAGES> <cDlgName1> [,<cDlgNameN>] ] ;
             [ <lPixel: PIXEL> ] ;
             [ <lDesign: DESIGN> ] ;
             [ <color: COLOR, COLORS> <nClrFore> [,<nClrBack>] ] ;
             [ OPTION <nOption> ] ;
             [ SIZE <nWidth>, <nHeight> ] ;
             [ MESSAGE <cMsg> ] ;
       => ;
          [<oFolder> := ] TFolder():New( <nRow>, <nCol>,;
             [\{<cPrompt>\}], \{<cDlgName1> [,<cDlgNameN>]\},;
             <oWnd>, <nOption>, <nClrFore>, <nClrBack>, <.lPixel.>,;
             <.lDesign.>, <nWidth>, <nHeight>, <cMsg> )

#xcommand REDEFINE FOLDER [<oFolder>] ;
             [ ID <nId> ] ;
             [ <of: OF, WINDOW, DIALOG> <oWnd> ] ;
             [ <prm: PROMPT, PROMPTS, ITEMS> <cPrompt,...> ] ;
             [ <dlg: DIALOG, DIALOGS, PAGE, PAGES> <cDlgName1> [,<cDlgNameN>] ] ;
             [ <color: COLOR, COLORS> <nClrFore> [,<nClrBack>] ] ;
             [ OPTION <nOption> ] ;
             [ ON CHANGE <uChange> ] ;
       => ;
          [<oFolder> := ] TFolder():ReDefine( <nId>, [\{<cPrompt>\}],;
             \{ <cDlgName1> [,<cDlgNameN>] \}, <oWnd>,;
             <nOption>, <nClrFore>, <nClrBack>,;
             [{|nOption,nOldOption| <uChange>}] )

//----------------------------------------------------------------------------//

#xcommand @ <nRow>, <nCol> TABS [<oTabs>] ;
             [ <of: OF, WINDOW, DIALOG> <oWnd> ] ;
             [ <prm: PROMPT, PROMPTS, ITEMS> <cPrompt,...> ] ;
             [ <act: ACTION, EXECUTE> <uAction> ] ;
             [ <lPixel: PIXEL> ] ;
             [ <lDesign: DESIGN> ] ;
             [ <color: COLOR, COLORS> <nClrFore> [,<nClrBack>] ] ;
             [ OPTION <nOption> ] ;
             [ SIZE <nWidth>, <nHeight> ] ;
             [ MESSAGE <cMsg> ] ;
       => ;
          [<oTabs> := ] TTabs():New( <nRow>, <nCol>,;
             [\{<cPrompt>\}], [{|nOption|<uAction>}],;
             <oWnd>, <nOption>, <nClrFore>, <nClrBack>, <.lPixel.>,;
             <.lDesign.>, <nWidth>, <nHeight>, <cMsg> )

#xcommand REDEFINE TABS [<oTabs>] ;
             [ ID <nId> ] ;
             [ <of: OF, WINDOW, DIALOG> <oWnd> ] ;
             [ <prm: PROMPT, PROMPTS, ITEMS> <cPrompt,...> ] ;
             [ <act: ACTION, EXECUTE> <uAction> ] ;
             [ <color: COLOR, COLORS> <nClrFore> [,<nClrBack>] ] ;
             [ OPTION <nOption> ] ;
       => ;
          [<oTabs> := ] TTabs():ReDefine( <nId>, [\{<cPrompt>\}],;
             [{|nOption|<uAction>}], <oWnd>, <nOption>, <nClrFore>, <nClrBack> )

//----------------------------------------------------------------------------//
// FiveWin Dialog TPages Class

#xcommand REDEFINE PAGES <oPag> ;
             [ ID <nId> ] ;
             [ OF <oWnd> ] ;
             [ DIALOGS <DlgName,...> ] ;
             [ OPTION <nOption> ] ;
       => ;
          <oPag> := TPages():Redefine( <nId>, <oWnd>, [{<DlgName>}], <nOption> )

#endif