Click above to get retro games delivered to your door ever month!

// FiveWin - Windows MAPI (mail services) support demonstration
// This is only for Windows for WorkGroups, Windows NT and Windows 95 !!!

#include "FiveWin.ch"
#include "Mail.ch"

static oWnd

//----------------------------------------------------------------------------//

function Main()

   local oBar

   DEFINE WINDOW oWnd TITLE "Using Windows MAIL Services"

   DEFINE BUTTONBAR oBar 3D SIZE 33, 33 OF oWnd

   DEFINE BUTTON OF oBar ACTION MsgInfo( MAPILogOn() ) ;
      MESSAGE "LogOn in the mail system" TOOLTIP "LogOn"

   DEFINE BUTTON OF oBar ;
      ACTION ( MAPILogOff(), MsgInfo( "MAIL LogOff done!" ) ) ;
      MESSAGE "LogOff from the mail system" TOOLTIP "LogOff"

   DEFINE BUTTON OF oBar GROUP ;
      ACTION InteractiveMessage() ;
      MESSAGE "Send an interactive message" TOOLTIP "Interactive"

   DEFINE BUTTON OF oBar ;
      ACTION DirectMessage();
      MESSAGE "Send a direct message" TOOLTIP "Direct"

   DEFINE BUTTON OF oBar GROUP ACTION oWnd:End() TOOLTIP "End"

   SET MESSAGE OF oWnd TO "FiveWin - Windows MAIL support" CENTERED

   ACTIVATE WINDOW oWnd ;
      VALID MsgYesNo( "Want to end ?" )

return nil

//----------------------------------------------------------------------------//

function InteractiveMessage()

   local oMail

   DEFINE MAIL oMail ;
      SUBJECT "Testing..." ;
      TEXT "This is real xBase power at your fingertips!" ;
      FROM USER ;
      RECEIPT

   ACTIVATE MAIL oMail

   MsgInfo( oMail:nRetCode )

return nil

//----------------------------------------------------------------------------//

function DirectMessage()

   local oMail

   DEFINE MAIL oMail ;
      SUBJECT "FiveWin Mail-control power" ;
      TEXT "This is real xBase power at your fingertips!" ;
      TO "LOLO", "Lolo Linares"

   ACTIVATE MAIL oMail

   MsgInfo( oMail:nRetCode )

return nil

//----------------------------------------------------------------------------//