Click above to get retro games delivered to your door ever month!

 RUN
 Execute a DOS command or program
------------------------------------------------------------------------------
 Syntax

     RUN | !* <xcCommandLine>

 Arguments

     <xcCommandLine> is any executable program including resident DOS
     commands and COMMAND.COM.  It may be specified either as a literal
     string or as a character expression enclosed in parentheses.

 Description

     RUN executes a DOS command or program from within a compiled
     application.  When you RUN a DOS program, CA-Clipper executes another
     copy of COMMAND.COM, passing the DOS command line at the same time.
     This has two implications.  First, you must have enough memory for
     COMMAND.COM (27K for DOS 3.2) and the program you wish to execute.
     Second, COMMAND.COM must be available on the path specified by COMSPEC
     (the default is the root directory of the disk where you boot DOS).  If
     COMMAND.COM is not located on this disk or the disk is changed, SET
     COMSPEC to the new location prior to running the CA-Clipper application.
     Note that SET DEFAULT and SET PATH have no effect on RUN.

     The ! form of the RUN command is provided for compatibility purposes
     only and therefore not recommended.

     Warning!  Do not RUN memory-resident programs from within CA-Clipper
     since you may lose memory when the control returns to your application
     program.

 Examples

     .  This example uses RUN with MEMOREAD() and MEMOWRIT() to create
        a user-defined function that calls a text editor with the current
        memo field:

        lSuccess = EditorMemo("Qedit", "Notes")
        RETURN

        FUNCTION EditorMemo( cEditor, cMemofld )
           IF MEMOWRIT("Clipedit.tmp", &cMemofld.)
              RUN (cEditor + " Clipedit.tmp")
              REPLACE &cMemofld. WITH MEMOREAD("Clipedit.tmp")
              ERASE Clipedit.tmp
              RETURN .T.
           ELSE
              RETURN .F.
           ENDIF

     .  One of the options you may want to give your users is direct
        access to DOS.  Do this with:

        RUN COMMAND

        To make it easier for the user to return to the application program,
        change the DOS prompt in the application batch file like this:

        REM Application Batch File
        ECHO OFF
        PROMPT DOS Access: Type EXIT to return to ;
                 application$_$p$g
        <your application program>
        PROMPT $p$g

        Then, instruct the user to execute the application batch file in
        place of the application .EXE file.

 Files:  Library is CLIPPER.LIB.